【.cmd】バッチファイルスクリプト %15 【.bat】

【.cmd】バッチファイルスクリプト %15 【.bat】 (819ﾚｽ)
上下前次 1-新

358: 2023/07/04(火)20:16 ID:dJR+6uCy(1) AAS
お疲れ

359: 2023/07/04(火)21:21 ID:+24T6cXg(1/2) AAS
ファイルの取り扱いにもよるけど
タイムスタンプでの管理はあまりよくないと思う
俺は結構ちょこちょこいじっちゃうのでタイムスタンプでは新旧の区別がつかなくなることが多い

360: 2023/07/04(火)21:30 ID:+24T6cXg(2/2) AAS
あとtmp,temp環境変数の書き換え
とくにフォルダとして使ってるものをファイル名にするのは危険
cmdの世界ではtmpがダメだがtempも使わないほうが良い

361: 2023/07/04(火)21:31 ID:9emtMuJF(1) AAS
リーズナブルな実装とは何だったのか

362: 2023/07/04(火)23:34 ID:LIey+Zab(4/5) AAS
temp の件は setlocal を使っているとはいえ、確かにタブーみたいなので変更しました。
タイムスタンプの件は、後でいじったファイルに対して再度作業を実行するかどうかの問題ですね。
そこら辺は、質問者が条件を書いてないので不明ですが、私はいじったファイルについても再度実行
するんじゃないかなと思ったので（それに簡単なので）そうしました。
1度実行したファイルには2度と実行しないのなら、終わったファイルはリネーム（例えば頭に _ を付加）
するとかして除外するか、終わったファイルリストを書き出してそれをチェックするとかですかね。
他のフォルダへ移動するのが最もいいと思うけど、なんだか都合が悪いみたいなので。

363: 2023/07/04(火)23:36 ID:LIey+Zab(5/5) AAS
@echo off
setlocal enabledelayedexpansion
set update=update.txt
set ichiji=temp.txt
set ignore=%update% %ichiji% %~nx0
set /A num=last=0
if exist %update% (
sort /R %update% > %ichiji%
set /P line=< %ichiji%
echo 前回更新日時 !line!
set last=!line:~,4!!line:~5,2!!line:~8,2!!line:~11,2!.!line:~14,2!
if "!line:~,16!"=="!date! !time:~,5!" (
set /A sec=160-1!time:~6,2!
echo 更新が早すぎます !sec! 秒お待ちください
:loop
if "!line:~11,5!"=="!time:~,5!" goto loop
)
) else echo 初回更新です
dir /A-D /OD | findstr /R "^20[0-9][0-9]" | findstr /V "%ignore%" > %ichiji%
for /F "delims=" %%f in (%ichiji%) do (
set line=%%f
set fname=!line:~36!
set ftime=!line:~,4!!line:~5,2!!line:~8,2!!line:~12,2!.!line:~15,2!
if !last! lss !ftime! (
echo [処理中] !fname! （処理をこの後に入れる）
set /A num+=1
)
)
if !num! neq 0 (
echo %date% %time:~0,5% >> %update%
echo !num! のファイルを更新し %update% に更新日時を追記しました
) else echo 更新ファイルはありません

364: 2023/07/05(水)06:45 ID:Ig34wRo0(1/3) AAS
time /t だと 06:00 なのに echo %time% だと 6:00:00.00 になる。
なんで、%time% だと頭の 0 がｽﾍﾟｰｽになるんだよ。
おかげで余計なバグができちゃったじゃないか。
というわけで、バグ取りました。って誰も見てないか・・・。

365: 2023/07/05(水)06:55 ID:Ig34wRo0(2/3) AAS
@echo off
setlocal enabledelayedexpansion
set dispskip=0
set update=update.txt
set ichiji=temp.txt
set ignore=%update% %ichiji% %~nx0
set /A num=last=0
if exist %update% (
sort /R %update% > %ichiji%
set /P line=< %ichiji%
echo 前回更新日時 !line!
set /A sec=160-1!time:~6,2!
if "!line:~,16!"=="!date! !time:~,5!" if sec gtr 2 echo 更新が早すぎます !sec! 秒お待ちください
:loop
if "!line:~11,5!"=="!time:~,5!" goto loop
set last=!line:~,4!!line:~5,2!!line:~8,2!.!line:~11,2!!line:~14,2!
if "!last:~9,1!"==" " set last=!last:~,9!0!last:~10!
) else echo 初回更新です
dir /A-D /OD | findstr /R "^20[0-9][0-9]" | findstr /V "%ignore%" > %ichiji%
for /F "delims=" %%f in (%ichiji%) do (
set line=%%f
set fname=!line:~36!
set ftime=!line:~,4!!line:~5,2!!line:~8,2!.!line:~12,2!!line:~15,2!
if !last! lss !ftime! (
echo [処理中] !fname! （処理をこの後に入れる）
set /A num+=1
) else if %dispskip% neq 0 echo スキップ !fname!
)
if !num! neq 0 (
echo !date! !time:~,5! >> %update%
echo !num! のファイルを更新し %update% に更新日時を追記しました
) else echo 更新ファイルはありません

366: 2023/07/05(水)12:49 ID:Ig34wRo0(3/3) AAS
よく見ると ! ではさむのを忘れとるじゃないか。

if "!line:~,16!"=="!date! !time:~,5!" if sec gtr 2 echo 更新が早すぎます !sec! 秒お待ちください

これは正しくはこうですね。（2秒以下の場合でも表示されていただけ）

if "!line:~,16!"=="!date! !time:~,5!" if !sec! gtr 2 echo 更新が早すぎます !sec! 秒お待ちください

367(1): 2023/07/05(水)12:59 ID:jlkBTxWV(1) AAS
powershellで書いたら1～数行だね
ふぅ

368: 2023/07/05(水)13:43 ID:hRO8F47X(1) AAS
数行なら書いて差し上げたら
もう見ていないかも知れないけど

369: 2023/07/05(水)18:25 ID:4rZ7+jZr(1) AAS
>>367
スレ違いとかいわないから後学のために記載して

370: 2023/07/05(水)23:14 ID:TBtlNfRd(1) AAS
バッチファイル不具合あるあるの日付またぎの対処が見当たらないな
やり直し

371: 2023/07/06(木)00:41 ID:X7484ET/(1/10) AAS
あぁ、もしかして、あれか、最後に update.txt に日付と時刻を追記する部分で、日付を取得した後、
時刻を取得する際に翌日になっているというまさに奇跡のタイミングのことを言ってるのか？
そんな時間にバッチを動かすとも思えんし、実際にその状態を発生させようと思っても起こらないだろう。
そのような超レアケースに無駄に頭と行を使うのはアホらしいが、まぁ、やってやるよ。

set date0=!date!
set time0=!time!
if not !date0!==!date! if !time0:,2! equ 0 set date0=!date!
echo !date0! !time0:~,5! >> %update%

はい、アップデート完了！

372: 2023/07/06(木)00:44 ID:X7484ET/(2/10) AAS
ごめん、~ が抜けてた。

set date0=!date!
set time0=!time!
if not !date0!==!date! if !time0:~,2! equ 0 set date0=!date!
echo !date0! !time0:~,5! >> %update%

373: 2023/07/06(木)00:50 ID:X7484ET/(3/10) AAS
まぁ、実際はその if 以下へたどりつくことは決してないだろうから、間違えていても同じかもな。

374: 2023/07/06(木)00:56 ID:X7484ET/(4/10) AAS
よく考えたらこれでも同じか。

set date0=!date!
set time0=!time!
if !time0:~,2! equ 0 set date0=!date!
echo !date0! !time0:~,5! >> %update%

375: 2023/07/06(木)07:56 ID:kQU1BcI/(1) AAS
考慮不要なレアケースではない。
例えば自ホストの時計がジョブスケジューラサーバ等の時計より少し遅れていると発生する。
「サンプルコードだから入れてない」なら分かる。

376: 2023/07/06(木)10:18 ID:X7484ET/(5/10) AAS
そんなのバッチの中で対応するより、自動バッチ実行する時刻を 0時にしなければいい。

そもそも、同じシステム上の同じバッチの同じ行で、date を取得した後 time を取得したら
日付が変わっていましたなんて、レア中のレア。
チャンスは1日に1回しかないし、発生させようと思ってやってみても絶対に無理だろ。
逆に、万一発生したらお祝いのメッセージを表示させたいぐらいだわ。

set date0=!date!
set time0=!time!
if not !date0!==!date! if !time0:~,2! equ 0 (
set date0=!date!
echo すばらしい！奇跡的なタイミング！おめでとう！
echo 0123456789a | choice /C a > nul
)
echo !date0! !time0:~,5! >> %update%

377: 2023/07/06(木)11:06 ID:X7484ET/(6/10) AAS
対策なしの 1行だった時よりも、対策して行を分けたことで、現象の発生率は上がるだろう。
それでも、実際に現象を発生させて動作検証をするのは絶対に無理だな。
まぁ、これでいいんじゃね？ただ、さすがに 10回ビープ音を鳴らすのはやりすぎたかな？

378: 2023/07/06(木)17:32 ID:T1YQhEvz(1/4) AAS
簡単バッチ。初回は処理しない。
２回目からendより新しいファイルを処理。

@echo off & chcp 65001 & set "a=begin" & set "b=end" & set "c="
if not exist "%b%" copy nul "%b%" & timeout /t 1
copy nul "%a%"
for /f "delims="eol^= %%i in ('dir /a-d-s-h /b /o-d') do (
if "%%i"=="%b%" (goto x) else if "%%i"=="%a%" (set c=1) else (
if defined c hoge.exe "%%i"))
:x
del "%b%" & ren "%a%" "%b%" & pause

379: 2023/07/06(木)18:41 ID:X7484ET/(7/10) AAS
それだと初回実行時より前のタイムスタンプのファイルは決して処理されないじゃん。
てか、コードページを変えたら戻しとけ。

380: 2023/07/06(木)18:47 ID:X7484ET/(8/10) AAS
いや、それより、一番の問題はファイルを処理したらそのファイルのタイムスタンプ変わるから、
毎回同じファイルを処理してしまうんじゃね？これはひどい。

381: 2023/07/06(木)19:55 ID:T1YQhEvz(2/4) AAS
すまん。書き直した。

@echo off & chcp 65001 & set "b=end"
for /f "delims="eol^= %%i in ('dir /a-d-s-h /b /o-d') do (
if "%%i"=="%b%" (goto x) else echo hoge.exe "%%i")
:x
copy nul "%b%" & chcp 932

これ、バッチ処理中に追加ファイルあると不味いな

382: 2023/07/06(木)22:30 ID:X7484ET/(9/10) AAS
早速の修正お疲れ様。
今回のは処理後即画面消える以外問題ないようだね。

で、勝手にいじらせてもらってリスト方式に変えてみた。
hoge.exe で処理したファイルの名前を list.txt に追記。
再度処理したければ、list.txt のそのファイルの行をエディタで削除。
これだと、バッチ処理中の追加ファイル問題も起こらない。

@echo off
chcp 65001
rem skip したファイルの名前を表示するフラグ
set f=1
set t=list.txt
if not exist %t% copy nul %t% > nul
for /f "delims="eol^= %%i in ('dir /a-d-s-h /b') do (
find "/%%i/" %t% > nul
if errorlevel 1 (
echo hoge.exe "%%i"
rem このバッチ中で処理する場合はここに入れる
echo /%%i/>> %t%
) else if %f% neq 0 echo skip "%%i"
)
pause
chcp 932

ところで、コードページを変えている理由は何？
hoge.exe に渡すファイル名関係か何か？

383: 2023/07/06(木)22:32 ID:gWNyo9yQ(1) AAS
最近はファイル名にユニコード文字を使うことも多いからなあ

384: 2023/07/06(木)22:54 ID:T1YQhEvz(3/4) AAS
どうもありがとう。
コードページはコマンド出力に影響する。
932だとユニコード特有な文字は変数に正しく入らない。
for %%i in (*) だと問題ないけど日時ソートされないし。
コードページが変わると画面が一旦消えるのが厄介。
65001だとバッチファイルの文字コードに注意。

385: 2023/07/06(木)23:08 ID:X7484ET/(10/10) AAS
高度なコードの解説ありがとう。
ファイル名には普通の半角文字しか使わないので知らなかった。
そういう場合については変えなくていいということかな？

386(1): 2023/07/06(木)23:12 ID:T1YQhEvz(4/4) AAS
コマンドのリダイレクトで化けない文字なら問題ないはず

387: 2023/07/07(金)04:34 ID:KFogdpBJ(1/2) AAS
おやじギャグ

上下前次 1-新書関写板覧索設栞歴

あと 432 ﾚｽあります
ｽﾚ情報赤ﾚｽ抽出画像ﾚｽ抽出歴の未読ｽﾚ

ぬこの手ぬこTOP 0.010s