【.cmd】バッチファイルスクリプト %12 【.bat】©2ch.net

[過去ﾛｸﾞ] 【.cmd】バッチファイルスクリプト %12 【.bat】©2ch.net (1002ﾚｽ)
上下前次 1-新

このｽﾚｯﾄﾞは過去ﾛｸﾞ倉庫に格納されています｡
次ｽﾚ検索歴削→次ｽﾚ栞削→次ｽﾚ過去ﾛｸﾞﾒﾆｭｰ

496(1): 2018/04/26(木)21:50 ID:5PgkCptO(1)調 AAS
適当でいいなら%CMDCMDLINE%

497: 2018/04/26(木)21:57 ID:vlAm5Lzz(1)調 AAS
%0 参照して分岐すれば？

echo %0
pause

498: 2018/04/26(木)22:30 ID:iUADfoHj(2/2)調 AAS
レスありがとうございます＞各位

すいませんダブルクリックと書いたのでミスリードになってしまったのですが、実際にはD&Dで引数も使用します。
なので>>496の環境変数参照して/Cオプション実行しているかどうかで分岐しようと思います。

499: 2018/04/27(金)01:23 ID:XIoO9rX1(1)調 AAS
ログファイルで確認するようにすればいいのに。

500: 2018/04/27(金)19:57 ID:CQ9eqs6l(1)調 AAS
え？

501(6): 2018/05/01(火)06:45 ID:aXoGd7xG(1)調 AAS
64桁の10進数を16進数に変換する方法、探したけど見つからなくて
バッチファイルだけでやるのは無理があるでしょうか。

javascriptでなら巨大な桁数いけるサイトはあったのですが
バッチファイル内で大量に処理したいのです。

502: 2018/05/01(火)08:40 ID:04a9c6T+(1/2)調 AAS
ネットワークカードに複数IPアドレスをバッチファイルで当てる方法教えてください。
netsh interface ipv4 set add name="ローカルエリア接続" static addr1="192.168.15.35" このあと
192.168.1.35も割り当てたい、よろしくお願いいたします。

503: 2018/05/01(火)08:45 ID:04a9c6T+(2/2)調 AAS
自己解決　netsh interface ip add address name="ローカルエリア接続" addr=192.168.1.35 mask=255.255.255.0

504(1): 2018/05/01(火)17:14 ID:cVB2iu29(1)調 AAS
>>501
取り敢えず、これでやったらどう？

https://technet.microsoft.com/ja-jp/sysinternals/hex2dec

505(2): 2018/05/01(火)23:59 ID:7h2ZqymN(1)調 AAS
>>501
普通の手段だと無理だと思う。
1. 整数演算はOSのbit数の上限までしかできない
2. 文字列として変換するにしても255⇒0xFFが限界

…。
3. そもそも符号無し16進？？有りの16進？？

506(1): 2018/05/02(水)00:09 ID:bQsnMWtx(1)調 AAS
>>501
ほぼ無理
自転車で崖を上がりたいというようなもの

あきらめて、これを機に何かの言語を覚えるといろいろな場面で一生使える
一番簡単なのはinstall不要なgawk

507(1): 505 2018/05/02(水)00:34 ID:69djG7nz(1)調 AAS
訂正。64bit環境でも調べたけど、最大2147483647（符号付32bitのMAX）だった。

508(1): 2018/05/02(水)02:01 ID:z5LQTSUi(1)調 AAS
>>504-507
ありがとうございます。hex2decは試行済でした。

1234567890000987654321000000
を渡すと
7766001854005038656 = 0x6BC6618A48FECE40
このように崩れます。

やはり無理がありますか。。。

gawkはlinuxのようですね。windowsで実現する方法を求めていました。
バッチファイルでは出来そうにないのでWSH JScriptあたりを探してみたりしていました。
他手段を探してみたいと思います。ありがとうございました。

509(3): 2018/05/02(水)03:07 ID:KFhIKBMV(1/5)調 AAS
ｂａｔでも出来るんだけど、実用な時間で出来るかと言われると何ともねえ
@echo off
setlocal
set hex=0123456789ABCDEF
set in=1234567890
set out=
set bin=
:loop
call :div2 in s
set bin=%s%%bin%
if defined in goto :loop
:loop2
set h=000%bin:~-4%
set /a h=("%h:~-4,1%<<3")+("%h:~-3,1%<<2")+("%h:~-2,1%<<1")+%h:~-1%
set bin=%bin:~0,-4%
call set out=%%hex:~%h%,1%%%out%
if defined bin goto :loop2
echo.0x%out%
endlocal
goto :eof
:div2
set dst=
set s=0
:divloop
set d=%in:~0,1%
set in=%in:~1%
set /a s=s*10+d
set /a h="s>>1"
set /a s%%=2
if defined dst (set dst=%dst%%h%) else if %h% gtr 0 set dst=%dst%%h%
if not defined in set in=%dst%&goto :eof
goto :divloop

510(1): 2018/05/02(水)03:13 ID:q7DG1Lgj(1)調 AAS
生きている間に終わらないってこと？

511: 2018/05/02(水)03:17 ID:KFhIKBMV(2/5)調 AAS
これはやっつけで作ったんで、もっとスマートにできるかも知れない
なお、div2ルーチンは最初変数を独立させるためにsetlocalで別環境にしてた名残が呼び出し元の引数に残ってる（無意味だから何で付けてるのって思わないように）

512: 2018/05/02(水)03:19 ID:KFhIKBMV(3/5)調 AAS
>>510
いや実際やってみればわかる
64桁程度なら一応待てる？？時間内で終わるよ？
inに10進数値をセットするが、%１に書き替えて起動時の引数で与えるようにすれば色々試せるだろう

513: 2018/05/02(水)06:44 ID:D/jExvSh(1)調 AAS
awkなら速くできるの？

514(3): 2018/05/02(水)07:02 ID:ESv7owpX(1)調 AAS
>>509
元の質問者じゃないけど、これ動かすとたまに「プロセスはファイルにアクセスできません。別のプロセスが使用中です。」って出る。
自分で書いたbatもループとかcallが多いとこれが出たりリダイレクトに失敗してたりする事があるんだけど何が原因？
ごくごく稀に飛ぶはずのないラベルに飛んで動作不良起こしたりもする。

515(1): 2018/05/02(水)18:25 ID:vWDYKqwa(1)調 AAS
>>508
これとかは？

ツール関係の小部屋
http://sky.geocities.jp/hp_gabo200x/room_tool.html

C-style arbitrary precision calculator
http://sky.geocities.jp/hp_gabo200x/mysoft/gcalc.lzh

516(1): 2018/05/02(水)21:55 ID:KFhIKBMV(4/5)調 AAS
>>514
OSは何だろう？
こっちは、win7pro 64bit
通常そういう変な動作はワークエリアが残ってない場合なんかに起きる
環境変数をいっぱい定義して領域が残ってないとか
そういう場合、コマンドプロンプトを一旦閉じて再度起動して初期状態にして試してみる
win2000で環境変数領域は2048バイト、winXPでは8192バイト、それ以外はヘルプにコマンドプロンプト関連のの説明が無い
でもまあ大抵はbatに問題がある
>>509のはこっちでは70桁を指定しても正常に動作してるが、
setlocalで子環境を作ってて、サブルーチンから抜けるときにはendlocal無しにgoto :eofしてるので
その辺が問題なのかもしれない
この辺はよく分からないので、一度setlocal,endlocalを削除して試してくれ

517(1): 2018/05/02(水)22:06 ID:KFhIKBMV(5/5)調 AAS
>>514
そのメッセージがbat実行直後なら（つまりあまりに瞬時で実行してるように思えない場合）、
本当にbatファイルが別プロセスで使用中なのかも知れない
裏で何かのプログラムがbatファイルを握って離さないとか
（インデックスサーチとかセキュリティチェックとかは、俺は作動させてないのでどうなのかは知らない）

518: 514 2018/05/03(木)05:58 ID:KZ8lRGiM(1)調 AAS
>>516-517
OSはwin10 64bitです。
セキュリティソフトはWindows Defender、インデックスサーチはWindows Search、Everythingを使ってます。
これらは利用者多いのに同様の不具合は聞いたこと無いから関係無いかも？
環境変数はいくつか自分で追加したけど問題になるほど登録してるとも思えないしよく分からない。
他になにか悪さをしているソフトがあるのかなあ。

519(1): 2018/05/03(木)11:45 ID:Ox4SBvDu(1/3)調 AAS
>>501
もう見てないかも知れないが、
俺の古いPCで、64桁で0.4秒ほどの実行時間です

@echo off
setlocal enabledelayedexpansion
set "a=1234567890123456789012345678901234567890123456789012345678901234"
set "g=0123456789ABCDEF"
set "h="
set /a b=8,e=100000000
for /L %%i in (8,8,56) do if not "!a:~%%i,1!"=="" set /a b=%%i+8
set "a=0000000%a%"
set "a=!a:~-%b%!"
for /L %%i in (%b%,-8,8) do set /a "a%%i=1!a:~-%%i,8!-e"
:x
set /a c=0,f=0
for /L %%i in (%b%,-8,8) do set /a "d=a%%i+c*e,a%%i=d>>4f|=a%%i,c=d&15"
set "h=!g:~%c%,1!%h%"
if %f% neq 0 goto x
for /f "delims=0 tokens=*" %%i in ("%h%") do set h=%%i
echo %h%
pause

520(1): 2018/05/03(木)18:33 ID:Ox4SBvDu(2/3)調 AAS
>>515 の gcalcを使用すると簡単

>type a
printf("%x\n", 1234567890123456789012345678901234567890123456789012345678901234)

>gcalc < a > b

>type b
0x30046030f26f462d7ac21a27eb9d53fff233c7acd12d87e96aff2

521: 2018/05/03(木)18:53 ID:Ox4SBvDu(3/3)調 AAS
すまん、printfの次の行にexitを追加して

522: 501 2018/05/04(金)16:14 ID:hkAWCjpW(1)調 AAS
>>509
>>519
すごい！ありがとうございます！
なんか微妙だなーと思って戻ってみたら凄いスマートなのリプきてた。

gcalcとも比較してみましたがかなり早いですね。?秒二桁くらい違う。
使わせていただきます。ありがとうございました！

523: 2018/05/04(金)23:52 ID:Ry3XO9FI(1)調 AAS
>>501
Ruby では、

num = 9999_1234567890_1234567890_1234567890_1234567890_1234567890_1234567890

num.to_s(16)
#=> "184e78450dd8c1fca3b502d65e4f6fb73c42c47ccff196ce3f0ad2"

524: 2018/05/05(土)00:20 ID:uOR+hZGm(1)調 AAS
dcなら

値1
値2
：
値n
16of

525: 2018/05/05(土)04:13 ID:nqyvYHZY(1)調 AAS
>>520
gcalc面白いね
こんな書き方が通っちゃうんだー

--bat--
@echo off
gcalc -d config(\"tab\",0), base(16), <in.txt; quit;
rem gcalc -d config(\"tab\",0), base2(16), <in.txt; quit;

--in.txt---
1111111111
2222222222
3333333333

526: 2018/05/14(月)16:02 ID:vCNzBA31(1)調 AAS
%1や環境変数が数字だけか判定するのが面倒
ぐぐってやりかたはわかったが、もっとすっきりくっきりな方法はないですか
正規表現だと ^\d+$ でおわりなのに

set W=x%1
set W=%W:0=%
set W=%W:1=%
set W=%W:2=%
set W=%W:3=%
set W=%W:4=%
set W=%W:5=%
set W=%W:6=%
set W=%W:7=%
set W=%W:8=%
set W=%W:9=%
if '%W%=='x echo 数字

527(2): 2018/05/14(月)16:37 ID:qPzKX5Gg(1)調 AAS
set X=100
echo %X%|findstr /X "[0-9][0-9]*"&&echo 数字

こうとか

528(2): 2018/05/15(火)01:55 ID:VsPlEm8N(1)調 AAS
@rem 2147483648 以上の数は扱えないため、大きい値が入る条件には不向き。

set "W=%1"
set DUMMY=a
set /A "DUMMY=W*1"
if not "%W%"=="%DUMMY%" (echo 数字以外) else echo 数字のみ

529: 2018/05/15(火)15:39 ID:Aaz/hbaw(1/2)調 AAS
>>528
-123 数字のみ

530: 2018/05/15(火)15:47 ID:Aaz/hbaw(2/2)調 AAS
0001 数字以外

531: 2018/05/16(水)00:05 ID:vNnFvDtx(1)調 AAS
ありがとうございます
>>527
findstって正規表現のようなことができるのですね、知らなかったです

>>528
英字だけ、数字だけだといいのですが、英数字混在文字列でエラーになりました
*1 の代わりに +0も同じでした

532(1): 2018/05/16(水)03:54 ID:Hrg3NbAG(1/6)調 AAS
@echo off
call :check_num %1 result
echo %result%
pause
goto :eof

:check_num
if "%~1"=="" set "b=FALSE" & goto :eof
for /f "delims=-+0123456789 tokens=* eol=" %%i in ("%~1") do (
set "a=%%i"
if defined a (set "b=FALSE") else set "b=TRUE"
)
endlocal & set "%2=%b%"

533: 2018/05/16(水)04:03 ID:Hrg3NbAG(2/6)調 AAS
>>532
7行目の :check_num の次の行に
setlocal
を追加願います

534(1): 2018/05/16(水)04:13 ID:Hrg3NbAG(3/6)調 AAS
なんか間違ってたので書き直した

@echo off
call :check_num %1 result
echo %result%
pause
goto :eof

:check_num
setlocal
if "%~1"=="" set "b=FALSE" & goto x
for /f "delims=-+0123456789 tokens=* eol=" %%i in ("%~1") do (
set "a=%%i"
if defined a (set "b=FALSE") else set "b=TRUE"
)
:x
endlocal & set "%2=%b%"

535: 2018/05/16(水)16:36 ID:VQztSlVV(1/4)調 AAS
1"2
result"=="" set "b=FALSE" & goto x の使い方が誤っています。

536: 2018/05/16(水)16:48 ID:VQztSlVV(2/4)調 AAS
"1"
TRUE
1"2"
ECHO は <OFF> です。

537: 2018/05/16(水)21:51 ID:Hrg3NbAG(4/6)調 AAS
引数の中の " の対策すると大変なんで、やりたくない
やりたい人、どうぞ

538(1): 2018/05/16(水)22:31 ID:VQztSlVV(3/4)調 AAS
1^2
1|2
1&2

539: 2018/05/16(水)23:12 ID:Hrg3NbAG(5/6)調 AAS
引数の中に cmd で特別な意味を持つ文字が有る場合は左に ^ を付けるか
全体を " で囲むしかないよ

540: 2018/05/16(水)23:15 ID:VQztSlVV(4/4)調 AAS
>>538は>>527宛て

>>534的には、1^^2

541: 2018/05/16(水)23:50 ID:Hrg3NbAG(6/6)調 AAS
FALSE になるようだが何か問題があるの？

542: 2018/05/17(木)00:05 ID:TsNh8oQN(1/9)調 AAS
ああ分かったリテラルが 1^2 の場合ね失礼

543: 2018/05/17(木)00:31 ID:TsNh8oQN(2/9)調 AAS
call :check_num "%~1" result
にでもすりゃいいのかな
こういうのは考え出すときりが無い様な気がするが

544: 2018/05/17(木)01:18 ID:zVFG07SK(1/5)調 AAS
分かってるのかどうか知らないが、
1"2"が、ECHO は <OFF> です。になるのは、eol="が効いてるため

545(1): 2018/05/17(木)06:56 ID:TsNh8oQN(3/9)調 AAS
eof= を消すと副作用があるし
どっちにしろ引数に ; があると誤動作するみたいだし
こりゃあもうお手上げだな

546: 2018/05/17(木)07:02 ID:TsNh8oQN(4/9)調 AAS
あ、eol= だった

547(1): 2018/05/17(木)07:11 ID:pqvSuRzJ(1)調 AAS
質問者が「もっとすっきりくっきりな方法」と言ってるんだから複雑でトリッキーな方法は求められてなないだろう

548: 2018/05/17(木)08:50 ID:zVFG07SK(2/5)調 AAS
>>545
>>269-273

549: 2018/05/17(木)09:36 ID:cmWUEZX7(1)調 AAS
>>547
いつもそうなるけど、バッチじゃ諦めろ、が正解になってしまうよｗ

550(2): 2018/05/17(木)10:17 ID:TsNh8oQN(5/9)調 AAS
どんな方法でも良いから
引数の中に " とか ; が入ってても
正しく動作するのを頼む

というのは絶対に無理なのかね

551: 2018/05/17(木)11:47 ID:TsNh8oQN(6/9)調 AAS
>>550が不可ならそれを前提条件にするしかないだろ
ちょっと直してみた
@echo off
call :check_num "%~1" result
echo %result% & pause & goto :eof
:check_num
setlocal
set "b=FALSE" & if "%~1"=="" goto x
for /f "delims=-+0123456789 tokens=*" %%i in ("%~1") do (
set "a=%%i" & if not defined a set "b=TRUE"
)
:x
endlocal & set "%2=%b%"

552(1): 2018/05/17(木)17:15 ID:TsNh8oQN(7/9)調 AAS
とりあえず引数の " と ; の対策らしきもの
引数は行末まで１個のみ
もう嫌気がさしたのでこれ以上はやめとく
@echo off
set a=%*"
set /a b=0,c=0
setlocal enabledelayedexpansion
:x
set d="!a:~%b%,1!!a:~%b%,1!"
if !d!=="" goto y
if !d!=="""" set /a c+=1
if !d!==";;" set /a c+=1
set /a b+=1 & goto x
:y
endlocal & set c=%c%
set "e=FALSE" & if %c% gtr 1 (goto z) else set "a=%*"
for /f "delims=-+0123456789 tokens=*" %%i in ("%a%") do (
set "a=%%i" & if not defined a set "e=TRUE"
)
:z
echo %e%

553(1): 2018/05/17(木)17:16 ID:zVFG07SK(3/5)調 AAS
>>550
@echo off
set "arg1=%1"
call :check_num arg1 result
echo %result% & pause & goto :eof
:check_num
setlocal EnableDelayedExpansion
set "b=FALSE"
for /f "delims=0123456789 tokens=*" %%i in ("!%1!") do (
set "a=%%i" & if not defined a set "b=TRUE"
)
:x
endlocal & set "%2=%b%"
goto :eof

引数に ; は指定できない（半角空白、カンマ、セミコロン、＝は引数の区切りを示すため）
なお、遅延環境変数の展開を使わないでも以下のようなチェックで最初に弾けば可能
if "%arg1:"=%" equ "%arg1:"=”%" (echo ^"なし) else echo ^"あり

554(1): 2018/05/17(木)17:18 ID:zVFG07SK(4/5)調 AAS
なお、+-は除くのが吉
+1+2-3

555(2): 2018/05/17(木)18:05 ID:TsNh8oQN(8/9)調 AAS
>554.bat 1"&ab"
'ab""' は、内部コマンドまたは外部コマンド、
操作可能なプログラムまたはバッチファイルとして認識されていません。
TRUE

556: 2018/05/17(木)21:22 ID:zVFG07SK(5/5)調 AAS
>>555
これ以上はファイル渡しにすべきだろう
set /p
or
for /f delimes^=^ tokens^=*^ eol^=

557: 2018/05/17(木)21:53 ID:TsNh8oQN(9/9)調 AAS
>>555
554.bat とあるが実際は >>553 のバッチ処理結果です
バッチ2行目の set コマンドの、左側の " が悪さをしてる
当然、下にあるチェック文もそのままでは使えない
引数 1;2 は実際には２つに分かれるが
これで TRUE を返すのは違和感あるので
>>552 では FALSE を返している
２つの %* を %1 にすれば TRUE を返せる筈

558: 2018/05/18(金)12:57 ID:CQAI+hTy(1)調 AAS
これが分からない

https://social.technet.microsoft.com/Forums/ja-JP/610268b2-c3f7-4e4f-8aa2-9d32353804e4?forum=win10itprogeneralJP

559: 2018/05/18(金)15:14 ID:nWqd9LPa(1)調 AAS
for /f %%i in ('"cmd /k prompt $h <nul"') do set BS=%%i
set /p AAA=".%BS%　　　必要ですか？(y/n）："

560: 2018/05/23(水)19:31 ID:Au5e7VGg(1)調 AAS
僕の知り合いの知り合いができたパソコン一台でお金持ちになれるやり方
役に立つかもしれません
グーグルで検索するといいかも『ネットで稼ぐ方法　モニアレフヌノ』

1FF18

561: 2018/05/24(木)10:48 ID:cPlRxlDn(1)調 AAS
1FF18

562(1): 2018/06/10(日)03:50 ID:TMZk6u5D(1/2)調 AAS
バッチファイルと同じ階層に複数のテキストファイルがあって、
バッチファイルに次々とドラッグ＆ドロップしたファイル名（拡張子含む）のみリスト化していくのは下記でできるのは分かったのですが…
@echo off
for %%f in (%*) do (
echo %%~nxf
) >> list.txt

しかし、バッチファイルと同じ階層（別の階層でも良いですが）に複数フォルダがあり、各フォルダ内にテキストファイルが複数ある場合に、
フォルダをバッチファイルに１つ１つD&Dすることにより、そのフォルダ内のファイル名（拡張子）のみリスト化していくコマンドが分からず詰まっています。
/rを使わずにわざわざ１つずつD&Dするのは、単にファイル名の順番ではなく、リスト化を意図した順番にしたいからです。
どなたかお願いします。

563: 2018/06/10(日)16:08 ID:fV9CYqGb(1)調 AAS
なんだって？

564(1): 2018/06/10(日)19:14 ID:UcKh88So(1)調 AAS
@echo off
cd /d "%~1"
for /r %%f in (*.txt) do (
echo %%~nxf
) >> "%~dp0list.txt"

565(1): 2018/06/10(日)20:30 ID:T1x52eBJ(1)調 AAS
まずは、
＞リスト化を意図した順番
これを詳しく説明するところからだな

566: 562 2018/06/10(日)20:59 ID:TMZk6u5D(2/2)調 AAS
>>564
できました
ありがとうございます！

>>565
意図した順番というのは、D&Dした順番、という意味でした

567: 2018/07/04(水)22:24 ID:gFgZc5FG(1)調 AAS
GTD

568: 2018/07/05(木)16:48 ID:AeL6VB/V(1)調 AAS
GTD

569(6): 2018/07/08(日)09:59 ID:48/+VLR1(1/2)調 AAS
ファイル名に半角スペースを含んで拡張子も一つじゃない複数のファイルをドロップしてファイルごとに処理したいんだけどどうfor書いたらいい？
今はこんな感じで書いてるんだけど半角スペースで切れちゃう
for %%f in (%*) do (
echo "%%~nxf"
)

570(1): 2018/07/08(日)17:55 ID:fq5YPvHI(1)調 AAS
>>569
それで問題なさそうなんだけど、
どういう問題なのか分からないから詳しく現象を説明してくれ

571(2): 2018/07/08(日)18:29 ID:48/+VLR1(2/2)調 AAS
>>570
ごめん半角じゃなくて全角スペースで切れてるみたいだ
"aaa　bbb.txt"
こうなるはずがファイル一つドロップするだけで↓になる
"aaa"
"bbb.txt"

572: 2018/07/08(日)19:34 ID:ayaOLpVg(1)調 AAS
>>569
forじゃないけど、こんなんじゃあかんの？

:loop
echo %~nx1
shift
if not "%~1"=="" goto :loop

573: 2018/07/08(日)20:03 ID:noo5aK3K(1)調 AAS
aaa　bbb.txtとかa&b.txtみたいなのは%1等で受け取っても切れるね
cmdの独特なコマンドラインパース処理が悪いともいえるし
半角スペース含まれてないのをいいことにD&D時にダブルクォートで囲わないOS側が悪いともいえるし困ったもんだな
D&Dで処理するのはスクリプト言語使った方がいいかもしれん

574: 2018/07/08(日)20:56 ID:O/180cHX(1/2)調 AAS
いまだにスペース問題抱えてるとは思わないよな
もう10数年以上前からあるのに

575(1): 2018/07/08(日)20:57 ID:3ARFRdhF(1)調 AAS
こういうの直すと互換性の問題でも起きるの？

576: 2018/07/08(日)21:45 ID:PKG5RTYD(1/3)調 AAS
>571
こうで良くないかなぁ？/d を使うパターン。

for /d %%f in (%*) do (
echo %%~nxf
)

>>575
そういう仕様に依存している過去のコードの動作に影響が出るのさ。
そういうコードは今までずっと企業内で使われている。
作者不詳のまま…

577: 2018/07/08(日)21:49 ID:PKG5RTYD(2/3)調 AAS
ごめん、/d でも全角はアウトですた。
わけわからーん

578: 2018/07/08(日)22:24 ID:vrRjc8/F(1/2)調 AAS
昔、どこかのサイトで似たようなの見たけど
%* を加工して解決しようとしてたが
数十行もあったようなｗ
でも、俺が動作確認したら全然ダメだったし

579(2): 2018/07/08(日)22:50 ID:E+arm29j(1/2)調 AAS
>>571
Windows 10 Home 1803 だけど全角空白も & も>>569で問題なく処理できるよ

580(1): 2018/07/08(日)22:57 ID:vrRjc8/F(2/2)調 AAS
>>579
引数はフルパスだからな
フォルダ名に半角スペースあるだろ

581: 2018/07/08(日)23:16 ID:dDjh6KF7(1)調 AAS
>>569
for の代わりに forfiles を使うと ""付きファイル名なのでうまくいく（たぶん）

582: 2018/07/08(日)23:36 ID:U6QPmMsx(1)調 AAS
>>569
全角スペースを文字として扱うか、半角スペースと同じように扱うかについて、
cmdは中途半端な扱いをしているようだしな。
フルパスに半角スペースがあると、全角スペースは文字として扱われるが、
フルパスに半角スペースがないと、全角スペースは半角スペースと同じ扱いになる。
しかもクォートしただけでは対処できないという困ったことに。

対処方法としては、フルパスの何処かに半角スペースを入れてクォートするだけ。

583(1): 2018/07/08(日)23:38 ID:PKG5RTYD(3/3)調 AAS
>>579
Win10 Pro 1803 64bit。
全角がアウト。

584: 2018/07/08(日)23:39 ID:O/180cHX(2/2)調 AAS
昔からある不具合なんだから互換性も糞もない

585: 2018/07/08(日)23:53 ID:E+arm29j(2/2)調 AAS
>>580 >>583
ああなるほど
すまん、ボケてたわ

586: 2018/07/09(月)00:39 ID:CF6LQR6B(1/6)調 AAS
全角空白の場合、ダブルクォーテーションで括られないのに、引数の区切り記号として取り扱われるってことか

間に、ダブルクォーテーションで括る操作をかませばいいか
@if (0)==(0) echo off
set arg=%*
for /f "delims=" %%f in ('cscript //nologo /e:jscript "%~f0" %%arg%%') do echo %%f
pause
goto :eof
@end
for(var i=0,arg=WScript.arguments;i<arg.length;i++) WScript.Echo('"'+arg(i)+'"');

587: 2018/07/09(月)00:46 ID:CF6LQR6B(2/6)調 AAS
いや引数を各行に分解したから、括る必要もないな
最終行訂正
for(var i=0,arg=WScript.arguments;i<arg.length;i++) WScript.Echo(arg(i));

588: 2018/07/09(月)01:05 ID:CF6LQR6B(3/6)調 AAS
やっぱり括ってたほうがトラブルが少ないかも
あと、半角空白が無いと括られないから、
a^b.txt
とかはBATに入ってくる時点でもうダメだな
%CMDCMDLINE%
とか見てやれば可能だけど

589: 2018/07/09(月)01:10 ID:CF6LQR6B(4/6)調 AAS
結論としては、色々苦労して対応するより、
必ず半角空白をいれたフォルダにファイルを置くようにしたほうがいいね

590: 2018/07/09(月)01:30 ID:M0pRa/sz(1/2)調 AAS
これらは""で括れば問題ない
a=b.txt
a;b.txt
a^b.txt

591: 2018/07/09(月)01:50 ID:M0pRa/sz(2/2)調 AAS
これは""で括ってもechoで化ける
%cd%.txt

592: 2018/07/09(月)21:52 ID:JZ4qv3b5(1)調 AAS
俺はバッチスクリプトを生成するスクリプトをPerlだのPhysonで書くときは
ダブルクォートで囲わずに全部キャレットでエスケープしてる。

今回の件は %* が勝手に全角空白で区切る仕様が駄目なんだけど…
スクリプトから呼ぶ場合には何とかなっても、D&Dの時点で引数を加工できないってとこに問題がある。
shift しても無駄、っていうところ…。

解決策…、ある？？俺は思いつかない…。

593: 2018/07/09(月)22:17 ID:FlHlLFRn(1)調 AAS
nbspでもなるな

594: 2018/07/09(月)22:21 ID:CF6LQR6B(5/6)調 AAS
a&b.txtとかはcmd. exeに入る前に対処しないとね
BAT以外の別スクリプトにD&Dして、そっちで引数を加工後にBATを呼んでもらうようにするぐらい

595: 2018/07/09(月)22:25 ID:CF6LQR6B(6/6)調 AAS
ところでcmdスレなのに、なんでcmd. exeがNGワードなんだよ

上下前次 1-新書関写板覧索設栞歴

あと 407 ﾚｽあります
ｽﾚ情報赤ﾚｽ抽出画像ﾚｽ抽出歴の未読ｽﾚ AAｻﾑﾈｲﾙ

ぬこの手ぬこTOP 1.643s*