【.cmd】 バッチファイルスクリプト %15 【.bat】 (764ﾚｽ)
上下前次1-新
715(6): デフォルトの名無しさん [sage] 2025/05/26(月) 08:47:40.30 ID:iONSO6k9(1) AAS
>>714714(4): デフォルトの名無しさん [] 2025/05/26(月) 00:46:53.22 ID:sddMzjz1(1/2) AAS
>>556
かなり前の書き込みなので もう見ていないかもしれないけど
使わせてもらいました ありがとうございます
初心者なので理解するのに時間がかかってしまいましたが
これで欠点が一つ克服できました
それでもいいけど最近シンプルなのに書き換えたので参考にどうぞ
ドラッグアンドドロップ用バッチのサンプル
@echo off & set arg=& set a="%cmdcmdline:"=" "%"
set a=%a:""=%& call :x %%a:*%~x0" =%%
echo コマンド %arg%
pause & exit
:x
set a=%1& if not defined a exit /b
if "%a:~1,1%"==" " set a=%a: =" "%
set arg=%arg% %a:""=%& shift & goto x
716: デフォルトの名無しさん [sage] 2025/05/26(月) 20:59:12.78 ID:mOG76bz3(1) AAS
>>715
何かわからんけど横からありがとう(・∀・)
717: デフォルトの名無しさん [] 2025/05/26(月) 23:38:19.16 ID:sddMzjz1(2/2) AAS
>>715
今でも改良を続けているんですね
調べてみて導入を検討してみようと思います
718(4): 714 [] 2025/06/09(月) 23:42:00.02 ID:XIEmLRR3(1) AAS
>>556,715556(3): デフォルトの名無しさん [sage] 2024/06/20(木) 06:56:43.32 ID:oAthcLJ7(1) AAS
私が普段使っているドラッグアンドドロップ用バッチのサンプルです
@echo off & set a="%cmdcmdline:"=%"& set "arg="
for /f "tokens=3* delims=:" %%i in (%a%) do (set a=%%i& set b=%%j)
set "a=%a:~-1%" & set b="%b::=" "%"
for %%i in (%b%) do set b=%%i& call :x
goto y
:x
if defined arg set arg=%arg:~0,-3%"
set arg=%arg% "%a%:%b:~1%& exit /b
:y
echo コマンド %arg%
pause & exit
2つを参考にして作ってみました
ドラッグ アンド ドロップ用
@echo off & set a="%cmdcmdline:"=%"
for /f "tokens=3* delims=:" %%i in (%a%) do (set a=%%i& set b=%%j)
set "a=%a:~-1%"
call :x "%a%:%%b: %a%:=" "%a%:%%"
:x
echo コマンド %*
pause & exit
719: デフォルトの名無しさん [sage] 2025/06/10(火) 16:46:13.85 ID:HbVriPvf(1) AAS
UNCパスに:は無い
おれの環境では試せないけど
どうなのかな
720: 714 [] 2025/06/11(水) 23:47:01.12 ID:h2Pmz4k5(1) AAS
UNCパスというのはネットワーク上のパスということですか
詳しくないのでよくわからないですけど
それがこのバッチに関係があるのでしょうか
721(1): デフォルトの名無しさん [sage] 2025/06/12(木) 06:01:52.53 ID:KDNtxLme(1) AAS
サーバの共有していないなら関係ない。
あるいはnet useでドライブ名を割当済でも関係ない。
問題なのはエクスプローラーで直接にUNCパスで移動して
そこでD&Dしたら"%~d1"は"\\"になるのでコロンが無いので
>>556や>>718では引数の分離ができない
722: 714 [] 2025/06/12(木) 23:37:30.69 ID:3VNaC5iR(1) AAS
>>721
説明ありがとうございます
UNCパスで移動中はこのバッチだと対応できないということですか
難しいですね
723: デフォルトの名無しさん [] 2025/06/13(金) 01:33:18.10 ID:QWIL1FR+(1/2) AAS
もう
@echo コマンド %1 %2 %3 %4 %5 %6 %7 %8 %9
@pause
で手を打とうよ。あとは運用。
724(1): デフォルトの名無しさん [sage] 2025/06/13(金) 01:41:39.04 ID:Vx46a8qY(1) AAS
>>715 で問題無いようだが
725(1): デフォルトの名無しさん [] 2025/06/13(金) 11:27:20.00 ID:QWIL1FR+(2/2) AAS
通りすがりで正直なにしてるのかわからんけど、もしかしてやりたいのはこゆこと?
@echo off
setlocal
set ARGS=
set ORIG_ARGS=%*
call :main %ORIG_ARGS: =[全角空白]%
goto :eof
:main
if x%1 == x goto :sort
set ARG=%1
set ARG=%ARG:[全角空白]= %
if not %ARG:~0,1%%ARG:~0,1% == "" set ARG="%ARG%"
set ARGS=%ARGS% %ARG%
shift
goto :main
:sort
for /F "delims=" %%F in ('dir /S/B/OD %ARGS%') do echo コマンド "%%F"
pause
726: デフォルトの名無しさん [sage] 2025/06/13(金) 17:53:07.75 ID:u+rmpblt(1) AAS
もういいからそれ
727(1): デフォルトの名無しさん [] 2025/06/13(金) 23:37:10.32 ID:lvrE3au7(1) AAS
>>725
試してみました
パスに全角スペースや半角スペースがあっても対応できるようですね
似たような方法を使ってるバッチをQiitaで見たことがあります
上手に回避できてると思いますがパスに&があると問題があります
%1 や %* では限界がある感じがするわ
728: デフォルトの名無しさん [sage] 2025/06/13(金) 23:50:46.94 ID:BURDJDsC(1) AAS
ややこしい処理は
呼び出し側で処理したいデータを環境変数にセット
BATは何もせずPythonを呼び出す
にすればすべて解決
729: デフォルトの名無しさん [sage] 2025/06/14(土) 04:23:27.36 ID:/OCzCvqy(1/2) AAS
環境変数てサイズに制限あるんで
大量のデータを渡す場合は普通にファイル渡しがいいかと。
親フォルダに半角スペースを入れてD&Dする方法もあるけど
それでも ab%cd%e.txt みたいのは化けるわけで
%* や %1 は取得時にすでに壊れてるのでどうにもならんわ
730(2): デフォルトの名無しさん [] 2025/06/14(土) 08:25:15.70 ID:yDCgYQHw(1/4) AAS
なるほど、あれの/Cオプションの引数にはあるけれど、あれがバッチに渡さないわけね
理解したんで あれ起動時のコマンドラインを愚直にパースするとこんな感じか
@echo off
setlocal enableDelayedExpansion
set CMDLINE=!CMDCMDLINE:*cmd" ="!
set Q="
set "S= "
set i=1
set ARG=
:loop
if !CMDLINE:~%i%! == !Q! goto :pause
set c=!CMDLINE:~%i%,1!
if !c! == !Q! (
call :Q
) else if not !c! == !S! (
call :NQ
) else (
set /a i += 1
)
goto :loop
続く
731(1): デフォルトの名無しさん [] 2025/06/14(土) 08:25:56.73 ID:yDCgYQHw(2/4) AAS
:Q
set ARG=!ARG!!c!
set /a i += 1
set c=!CMDLINE:~%i%,1!
if not !c! == !Q! goto :Q
set ARG=!ARG!!Q!
call :exec
set ARG=
set /a i += 1
goto :eof
:NQ
set ARG=!ARG!!c!
set /a i += 1
set c=!CMDLINE:~%i%,1!
if not !c! == !Q! if not !c! == !S! goto :NQ
set ARG="!ARG!"
call :exec
set ARG=
goto :eof
:exec
echo コマンド !ARG!
goto :eof
:pause
pause
732: デフォルトの名無しさん [] 2025/06/14(土) 08:41:58.61 ID:yDCgYQHw(3/4) AAS
あ、ソート忘れたけどいいよね
文字化けするならforの前にchcp 65001入れておくれ
733(1): デフォルトの名無しさん [] 2025/06/14(土) 15:14:17.65 ID:eF2X+eHO(1) AAS
なにかおかしいと思ってたんだが
これ拡張子が.cmd のバッチファイルを想定してあるんだな
.bat だと無限ループするから変だと思った
734(2): 外野 [sage] 2025/06/14(土) 16:09:26.74 ID:/OCzCvqy(2/2) AAS
>>718 参考に作ってみた。拡張子bat。UNCパスOK。違ってたらごめん
@echo off & set "a=%cmdcmdline:"=%"
set "a=%a:*.bat=%" & call set arg="%%a: %~d1=" "%~d1%%"
echo コマンド %arg:* =% & pause
735: デフォルトの名無しさん [] 2025/06/14(土) 16:43:38.20 ID:yDCgYQHw(4/4) AAS
>>733
そういうことなら set CMDLINE= の行を
set CMDLINE=!CMDCMDLINE:*%~x0" ="!
にすれば .cmd でも .bat でも .Cmd でも .BAT でもおけだな
736(2): デフォルトの名無しさん [] 2025/06/15(日) 07:57:25.07 ID:sG85beXD(1) AAS
>>730-731 に重大な欠陥があった
全角空白 とアンパサンド&echo.この文が単独で表示されたらダメ&pause
というファイル名を試したらダメだった
最後の行のpauseの後にexitを入れてcmd.ехеを終わらせる必要があった
これで >>727 は直せたはずだけどまだあったら指摘してください
なおUNCパス上でも動作に問題なし
737: 外野 [sage] 2025/06/15(日) 10:50:38.73 ID:ZhGW5ICb(1/2) AAS
>>718
>>736さんの件で >>734 もexitを追加する必要があるようだ
738: デフォルトの名無しさん [] 2025/06/15(日) 13:37:57.77 ID:E4ppjALA(1) AAS
>>736
試したけどファイル名の表示までは問題ないし
意図していない動作には違いないけど
余計な文字とpauseが1回余分に出るだけだね
739: 外野 [sage] 2025/06/15(日) 14:22:10.67 ID:ZhGW5ICb(2/2) AAS
pauseだと無害だけどdelだったらヤバいみたいな
740(1): デフォルトの名無しさん [] 2025/06/16(月) 07:47:57.49 ID:FL2oCcdJ(1/6) AAS
>>734
2行目を
call set "a=%%a:*%~x0 =%%" & call set arg="%%a: %~d1=" "%~d1%%"
にすると .cmd 派としては嬉しい
ついでに %arg% に手を加えなくてもすむ
741(1): デフォルトの名無しさん [sage] 2025/06/16(月) 12:04:25.57 ID:3rn8pxf/(1/4) AAS
>>740さんの指摘で訂正しました。ありがとう
@echo off & set "a=%cmdcmdline:"=%"
call set "a=%%a:*%~x0 =%%" & call set arg="%%a: %~d1=" "%~d1%%"
echo コマンド %arg%
pause & exit
ちなみに最後の exit が無いと a&b.txt をD&Dしたら
バッチ終了後に既存の b.txt が勝手に開きました
(フルパス空白無しの場合)
742: デフォルトの名無しさん [sage] 2025/06/16(月) 12:25:15.13 ID:CXTiNK7e(1) AAS
こんな有様でもDOSの頃は良かったんだけどね
Windowsで規制解除した時にエスケープ決めておけば
743(1): デフォルトの名無しさん [sage] 2025/06/16(月) 12:56:05.32 ID:h70+cne9(1/2) AAS
昔はD&Dなんて無かったからなあ
744(1): デフォルトの名無しさん [] 2025/06/16(月) 20:18:24.83 ID:FL2oCcdJ(2/6) AAS
>>741
改良提案したのにごめん、%1に依存してるからNGかもと気づいた
ファイル名でなくディレクトリ名に & があって、パス全体では空白がない場合たぶんNG
745: デフォルトの名無しさん [sage] 2025/06/16(月) 21:12:33.56 ID:3rn8pxf/(2/4) AAS
>>744
それは無いと思います
最初に引用符を全部削除して、%0と%1の間は空白一個です
最後に両側に引用符を付けています
だから引数は全て引用符に囲まれている
746: デフォルトの名無しさん [] 2025/06/16(月) 21:23:14.37 ID:FL2oCcdJ(3/6) AAS
>>730 にもちょっとあれ表記で書いたけど
cmd.ехеがバッチを起動するときにクオートされてない & までしかバッチに渡さないんだよ
だから%1は&の前までしか入らない
747: デフォルトの名無しさん [] 2025/06/16(月) 21:47:39.98 ID:FL2oCcdJ(4/6) AAS
あ、それでもいいのか? ごめん
748: デフォルトの名無しさん [sage] 2025/06/16(月) 22:03:48.18 ID:3rn8pxf/(3/4) AAS
%cmdcmdline%を見ると%0は必ず引用符で囲まれている
%~d1はドライブ名なので最初の2文字だけですね
749: デフォルトの名無しさん [] 2025/06/16(月) 22:12:19.82 ID:FL2oCcdJ(5/6) AAS
空白とパスの頭に一致すればいいんだから%1が&の前まででも十分で
それこそ %~d1 の代わりに %a:~1,2% でもいいわけだ
はやとちりしてすまん
750: デフォルトの名無しさん [sage] 2025/06/16(月) 22:24:14.65 ID:3rn8pxf/(4/4) AAS
あ、今気付いたけどバッチ自体のフルパスに%があると不味いですね
%cd%.bat とかふざけた名前を付けると起動すらしない(笑)
751: デフォルトの名無しさん [] 2025/06/16(月) 22:28:11.29 ID:FL2oCcdJ(6/6) AAS
あ、%~d1 を使う段階ではまだaの頭に " がないから %a:~0,2% か
今日はダメすぎる…
752(1): デフォルトの名無しさん [sage] 2025/06/16(月) 22:43:47.80 ID:rarg6+Me(1) AAS
>>743
過去ログとか見てみると
ドロップして動画変換したいと言ってる人がいたけど
バッチにドロップするという概念がなかったって人もいたわ
D&Dは新しい変化といえるのかな
753: デフォルトの名無しさん [sage] 2025/06/16(月) 23:13:16.42 ID:h70+cne9(2/2) AAS
そもそも昔はマウスが…
754: デフォルトの名無しさん [sage] 2025/06/17(火) 01:09:51.80 ID:iFChncGT(1) AAS
>>752
それほとんど使わないし
ファイルのDDで誤ってバッチに突っ込んだりするから
機能停止したい
755(1): デフォルトの名無しさん [sage] 2025/06/17(火) 01:48:49.47 ID:k94ULtHo(1/2) AAS
Windows11で新しいターミナルになって
せっかく画面に複数ファイルD&Dできるようになったのに
やっぱりスペースのないやつは " 付かない
馬鹿なのか
756: デフォルトの名無しさん [sage] 2025/06/17(火) 16:27:15.74 ID:tmeQgGUx(1/2) AAS
Windowsにはライブラリという機能があってな
複数の場所のファイルをまとめて管理できる
エクスプローラーではデフォルト非表示だけど
有効にすると別のドライブのファイルもドラッグ&ドロップができたり
757(2): >>724 [sage] 2025/06/17(火) 18:10:43.80 ID:+VkCgLWJ(1) AAS
だから >>715 で問題ないと言ってるだろ
いったい何を試行錯誤してんだ
758: デフォルトの名無しさん [sage] 2025/06/17(火) 22:17:05.18 ID:tmeQgGUx(2/2) AAS
解説がなかったからだろ
759: デフォルトの名無しさん [sage] 2025/06/17(火) 23:21:34.27 ID:v63kiG1M(1) AAS
>>757
確かに >>715 は UNCパスやドライブ文字が違うファイル
にも対応できてる すごいバッチだと思います
>>718 は行数は少ないけどドライブ文字を流用してるから手抜きではありますね
760: デフォルトの名無しさん [sage] 2025/06/17(火) 23:56:02.26 ID:k94ULtHo(2/2) AAS
>>757
まあ冗長だと思ったからじゃね
761: デフォルトの名無しさん [sage] 2025/06/21(土) 00:15:12.24 ID:UJBDQV9Q(1/2) AAS
>>755
ターミナルのコマンドライン引数は ; が区切り文字らしいので
バッチのパスや引数に ; があると別のタブができちゃう
弱点が増えてよかったね
762: デフォルトの名無しさん [sage] 2025/06/21(土) 09:18:33.42 ID:P2MDKzd7(1) AAS
;って元々区切り文字じゃね
763: デフォルトの名無しさん [sage] 2025/06/21(土) 23:59:59.67 ID:UJBDQV9Q(2/2) AAS
バッチのパスに ; があってもCMDは起動できる
ターミナルだと起動できない " で囲んでもダメ
764: デフォルトの名無しさん [sage] 2025/06/22(日) 01:31:14.42 ID:GoovCRBR(1) AAS
ああPowerShellの話か
上下前次1-新書関写板覧索設栞歴
ｽﾚ情報 赤ﾚｽ抽出 画像ﾚｽ抽出 歴の未読ｽﾚ AAｻﾑﾈｲﾙ
ぬこの手 ぬこTOP 1.302s*